Mercurial > hg > CbC > CbC_llvm

comparison CMakeLists.txt @ 0:95c75e76d11b LLVM3.4

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
LLVM 3.4
author Kaito Tokumori <e105711@ie.u-ryukyu.ac.jp>
date Thu, 12 Dec 2013 13:56:28 +0900
parents
children e4204d083e25
comparison
equal deleted inserted replaced
-1:000000000000 0:95c75e76d11b
1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
2
3 project(LLVM)
4 cmake_minimum_required(VERSION 2.8)
5
6 # Add path for custom modules
7 set(CMAKE_MODULE_PATH
8 ${CMAKE_MODULE_PATH}
9 "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
10 "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
11 )
12
13 set(LLVM_VERSION_MAJOR 3)
14 set(LLVM_VERSION_MINOR 4)
15
16 if (NOT PACKAGE_VERSION)
17 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
18 endif()
19
20 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
21
22 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
23 if ( LLVM_USE_FOLDERS )
24 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
25 endif()
26
27 include(VersionFromVCS)
28
29 option(LLVM_APPEND_VC_REV
30 "Append the version control system revision id to LLVM version" OFF)
31
32 if( LLVM_APPEND_VC_REV )
33 add_version_info_from_vcs(PACKAGE_VERSION)
34 endif()
35
36 set(PACKAGE_NAME LLVM)
37 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
38 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
39
40 # Configure CPack.
41 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
42 set(CPACK_PACKAGE_VENDOR "LLVM")
43 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
44 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
45 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
46 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
47 if(WIN32 AND NOT UNIX)
48 set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
49 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
50 set(CPACK_NSIS_MODIFY_PATH "ON")
51 set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
52 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
53 "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
54 set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
55 "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
56 endif()
57 include(CPack)
58
59 # Sanity check our source directory to make sure that we are not trying to
60 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
61 # sure that we don't have any stray generated files lying around in the tree
62 # (which would end up getting picked up by header search, instead of the correct
63 # versions).
64 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
65 message(FATAL_ERROR "In-source builds are not allowed.
66 CMake would overwrite the makefiles distributed with LLVM.
67 Please create a directory and run cmake from there, passing the path
68 to this source directory as the last argument.
69 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
70 Please delete them.")
71 endif()
72 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
73 file(GLOB_RECURSE
74 tablegenned_files_on_include_dir
75 "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
76 file(GLOB_RECURSE
77 tablegenned_files_on_lib_dir
78 "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
79 if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
80 message(FATAL_ERROR "Apparently there is a previous in-source build,
81 probably as the result of running `configure' and `make' on
82 ${CMAKE_CURRENT_SOURCE_DIR}.
83 This may cause problems. The suspicious files are:
84 ${tablegenned_files_on_lib_dir}
85 ${tablegenned_files_on_include_dir}
86 Please clean the source directory.")
87 endif()
88 endif()
89
90 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
91
92 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
93 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
94 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
95 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
96 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
97 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
98
99 set(LLVM_ALL_TARGETS
100 AArch64
101 ARM
102 CppBackend
103 Hexagon
104 Mips
105 MSP430
106 NVPTX
107 PowerPC
108 R600
109 Sparc
110 SystemZ
111 X86
112 XCore
113 )
114
115 # List of targets with JIT support:
116 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
117
118 set(LLVM_TARGETS_TO_BUILD "all"
119 CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
120
121 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
122 CACHE STRING "Semicolon-separated list of experimental targets to build.")
123
124 option(BUILD_SHARED_LIBS
125 "Build all libraries as shared libraries instead of static" OFF)
126
127 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
128 if(LLVM_ENABLE_CBE_PRINTF_A)
129 set(ENABLE_CBE_PRINTF_A 1)
130 endif()
131
132 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
133 if(LLVM_ENABLE_TIMESTAMPS)
134 set(ENABLE_TIMESTAMPS 1)
135 endif()
136
137 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
138 if(LLVM_ENABLE_BACKTRACES)
139 set(ENABLE_BACKTRACES 1)
140 endif()
141
142 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
143 if(LLVM_ENABLE_CRASH_OVERRIDES)
144 set(ENABLE_CRASH_OVERRIDES 1)
145 endif()
146
147 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
148 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
149 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
150
151 set(LLVM_TARGET_ARCH "host"
152 CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
153
154 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
155
156 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
157
158 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
159
160 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
161 set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
162 endif()
163
164 set(LLVM_TARGETS_TO_BUILD
165 ${LLVM_TARGETS_TO_BUILD}
166 ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
167 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
168
169 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
170
171 include(AddLLVMDefinitions)
172
173 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
174
175 # MSVC has a gazillion warnings with this.
176 if( MSVC )
177 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
178 else( MSVC )
179 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
180 endif()
181
182 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
183 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
184
185 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
186 option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
187 else()
188 option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
189 endif()
190
191 option(LLVM_USE_INTEL_JITEVENTS
192 "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
193 OFF)
194
195 if( LLVM_USE_INTEL_JITEVENTS )
196 # Verify we are on a supported platform
197 if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
198 message(FATAL_ERROR
199 "Intel JIT API support is available on Linux and Windows only.")
200 endif()
201 endif( LLVM_USE_INTEL_JITEVENTS )
202
203 option(LLVM_USE_OPROFILE
204 "Use opagent JIT interface to inform OProfile about JIT code" OFF)
205
206 # If enabled, verify we are on a platform that supports oprofile.
207 if( LLVM_USE_OPROFILE )
208 if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
209 message(FATAL_ERROR "OProfile support is available on Linux only.")
210 endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
211 endif( LLVM_USE_OPROFILE )
212
213 set(LLVM_USE_SANITIZER "" CACHE STRING
214 "Define the sanitizer used to build binaries and tests.")
215
216 option(LLVM_USE_SPLIT_DWARF
217 "Use -gsplit-dwarf when compiling llvm." OFF)
218
219 # Define an option controlling whether we should build for 32-bit on 64-bit
220 # platforms, where supported.
221 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
222 # TODO: support other platforms and toolchains.
223 option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
224 endif()
225
226 # Define the default arguments to use with 'lit', and an option for the user to
227 # override.
228 set(LIT_ARGS_DEFAULT "-sv")
229 if (MSVC OR XCODE)
230 set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
231 endif()
232 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
233
234 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
235 if( WIN32 AND NOT CYGWIN )
236 set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
237 endif()
238
239 # Define options to control the inclusion and default build behavior for
240 # components which may not strictly be necessary (tools, examples, and tests).
241 #
242 # This is primarily to support building smaller or faster project files.
243 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
244 option(LLVM_BUILD_TOOLS
245 "Build the LLVM tools. If OFF, just generate build targets." ON)
246
247 option(LLVM_BUILD_RUNTIME
248 "Build the LLVM runtime libraries." ON)
249 option(LLVM_BUILD_EXAMPLES
250 "Build the LLVM example programs. If OFF, just generate build targets." OFF)
251 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
252
253 option(LLVM_BUILD_TESTS
254 "Build LLVM unit tests. If OFF, just generate build targets." OFF)
255 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
256
257 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
258 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
259 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
260
261 # All options referred to from HandleLLVMOptions have to be specified
262 # BEFORE this include, otherwise options will not be correctly set on
263 # first cmake run
264 include(config-ix)
265
266 # By default, we target the host, but this can be overridden at CMake
267 # invocation time.
268 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
269 "Default target for which LLVM will generate code." )
270 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
271
272 include(HandleLLVMOptions)
273
274 # Verify that we can find a Python 2 interpreter. Python 3 is unsupported.
275 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
276 include(FindPythonInterp)
277 if( NOT PYTHONINTERP_FOUND )
278 message(FATAL_ERROR
279 "Unable to find Python interpreter, required for builds and testing.
280
281 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
282 endif()
283
284 ######
285 # LLVMBuild Integration
286 #
287 # We use llvm-build to generate all the data required by the CMake based
288 # build system in one swoop:
289 #
290 # - We generate a file (a CMake fragment) in the object root which contains
291 # all the definitions that are required by CMake.
292 #
293 # - We generate the library table used by llvm-config.
294 #
295 # - We generate the dependencies for the CMake fragment, so that we will
296 # automatically reconfigure outselves.
297
298 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
299 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
300 "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
301 set(LLVMBUILDCMAKEFRAG
302 "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
303
304 # Create the list of optional components that are enabled
305 if (LLVM_USE_INTEL_JITEVENTS)
306 set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
307 endif (LLVM_USE_INTEL_JITEVENTS)
308 if (LLVM_USE_OPROFILE)
309 set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
310 endif (LLVM_USE_OPROFILE)
311
312 message(STATUS "Constructing LLVMBuild project information")
313 execute_process(
314 COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
315 --native-target "${LLVM_NATIVE_ARCH}"
316 --enable-targets "${LLVM_TARGETS_TO_BUILD}"
317 --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
318 --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
319 --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
320 OUTPUT_VARIABLE LLVMBUILDOUTPUT
321 ERROR_VARIABLE LLVMBUILDERRORS
322 OUTPUT_STRIP_TRAILING_WHITESPACE
323 ERROR_STRIP_TRAILING_WHITESPACE
324 RESULT_VARIABLE LLVMBUILDRESULT)
325
326 # On Win32, CMake doesn't properly handle piping the default output/error
327 # streams into the GUI console. So, we explicitly catch and report them.
328 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
329 message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
330 endif()
331 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
332 message(FATAL_ERROR
333 "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
334 endif()
335
336 # Include the generated CMake fragment. This will define properties from the
337 # LLVMBuild files in a format which is easy to consume from CMake, and will add
338 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
339 # files change.
340 include(${LLVMBUILDCMAKEFRAG})
341
342 ######
343
344 # Configure all of the various header file fragments LLVM uses which depend on
345 # configuration variables.
346 set(LLVM_ENUM_TARGETS "")
347 set(LLVM_ENUM_ASM_PRINTERS "")
348 set(LLVM_ENUM_ASM_PARSERS "")
349 set(LLVM_ENUM_DISASSEMBLERS "")
350 foreach(t ${LLVM_TARGETS_TO_BUILD})
351 set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
352
353 list(FIND LLVM_ALL_TARGETS ${t} idx)
354 list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
355 if( idx LESS 0 AND idy LESS 0 )
356 message(FATAL_ERROR "The target `${t}' does not exist.
357 It should be one of\n${LLVM_ALL_TARGETS}")
358 else()
359 set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
360 endif()
361
362 file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
363 if( asmp_file )
364 set(LLVM_ENUM_ASM_PRINTERS
365 "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
366 endif()
367 if( EXISTS ${td}/AsmParser/CMakeLists.txt )
368 set(LLVM_ENUM_ASM_PARSERS
369 "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
370 endif()
371 if( EXISTS ${td}/Disassembler/CMakeLists.txt )
372 set(LLVM_ENUM_DISASSEMBLERS
373 "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
374 endif()
375 endforeach(t)
376
377 # Produce the target definition files, which provide a way for clients to easily
378 # include various classes of targets.
379 configure_file(
380 ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
381 ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
382 )
383 configure_file(
384 ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
385 ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
386 )
387 configure_file(
388 ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
389 ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
390 )
391 configure_file(
392 ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
393 ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
394 )
395
396 # Configure the three LLVM configuration header files.
397 configure_file(
398 ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
399 ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
400 configure_file(
401 ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
402 ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
403 configure_file(
404 ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
405 ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
406
407 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
408 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
409 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
410
411 set(CMAKE_INCLUDE_CURRENT_DIR ON)
412
413 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
414
415 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
416 # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
417 # with libxml2, iconv.h, etc., we must add /usr/local paths.
418 include_directories("/usr/local/include")
419 link_directories("/usr/local/lib")
420 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
421
422 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
423 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
424 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
425
426 # Make sure we don't get -rdynamic in every binary. For those that need it,
427 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
428 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
429
430 include(AddLLVM)
431 include(TableGen)
432
433 if( MINGW )
434 # People report that -O3 is unreliable on MinGW. The traditional
435 # build also uses -O2 for that reason:
436 llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
437 endif()
438
439 # Put this before tblgen. Else we have a circular dependence.
440 add_subdirectory(lib/Support)
441 add_subdirectory(lib/TableGen)
442
443 add_subdirectory(utils/TableGen)
444
445 add_subdirectory(include/llvm)
446
447 add_subdirectory(lib)
448
449 add_subdirectory(utils/FileCheck)
450 add_subdirectory(utils/FileUpdate)
451 add_subdirectory(utils/count)
452 add_subdirectory(utils/not)
453 add_subdirectory(utils/llvm-lit)
454 add_subdirectory(utils/yaml-bench)
455
456 add_subdirectory(projects)
457
458 if( LLVM_INCLUDE_TOOLS )
459 add_subdirectory(tools)
460 endif()
461
462 if( LLVM_INCLUDE_EXAMPLES )
463 add_subdirectory(examples)
464 endif()
465
466 if( LLVM_INCLUDE_TESTS )
467 add_subdirectory(test)
468 add_subdirectory(utils/unittest)
469 add_subdirectory(unittests)
470 if (MSVC)
471 # This utility is used to prevent crashing tests from calling Dr. Watson on
472 # Windows.
473 add_subdirectory(utils/KillTheDoctor)
474 endif()
475
476 # Add a global check rule now that all subdirectories have been traversed
477 # and we know the total set of lit testsuites.
478 get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
479 get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
480 get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
481 get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
482 add_lit_target(check-all
483 "Running all regression tests"
484 ${LLVM_LIT_TESTSUITES}
485 PARAMS ${LLVM_LIT_PARAMS}
486 DEPENDS ${LLVM_LIT_DEPENDS}
487 ARGS ${LLVM_LIT_EXTRA_ARGS}
488 )
489 endif()
490
491 if (LLVM_INCLUDE_DOCS)
492 add_subdirectory(docs)
493 endif()
494
495 add_subdirectory(cmake/modules)
496
497 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
498 install(DIRECTORY include/
499 DESTINATION include
500 FILES_MATCHING
501 PATTERN "*.def"
502 PATTERN "*.h"
503 PATTERN "*.td"
504 PATTERN "*.inc"
505 PATTERN "LICENSE.TXT"
506 PATTERN ".svn" EXCLUDE
507 )
508
509 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
510 DESTINATION include
511 FILES_MATCHING
512 PATTERN "*.def"
513 PATTERN "*.h"
514 PATTERN "*.gen"
515 PATTERN "*.inc"
516 # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
517 PATTERN "CMakeFiles" EXCLUDE
518 PATTERN ".svn" EXCLUDE
519 )
520 endif()
521
522 # Workaround for MSVS10 to avoid the Dialog Hell
523 # FIXME: This could be removed with future version of CMake.
524 if(MSVC_VERSION EQUAL 1600)
525 set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
526 if( EXISTS "${LLVM_SLN_FILENAME}" )
527 file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
528 endif()
529 endif()
530