{-# OPTIONS --allow-unsolved-metas #-}
import Level
open import Ordinals
module generic-filter {n : Level.Level } (O : Ordinals {n})   where

import filter
open import zf
open import logic
-- open import partfunc {n} O
import OD

open import Relation.Nullary
open import Relation.Binary
open import Data.Empty
open import Relation.Binary
open import Relation.Binary.Core
open import Relation.Binary.PropositionalEquality
open import Data.Nat
import BAlgebra

open BAlgebra O

open inOrdinal O
open OD O
open OD.OD
open ODAxiom odAxiom
import OrdUtil
import ODUtil
open Ordinals.Ordinals  O
open Ordinals.IsOrdinals isOrdinal
open Ordinals.IsNext isNext
open OrdUtil O
open ODUtil O


import ODC

open filter O

open _∧_
open _∨_
open Bool


open HOD

-------
--    the set of finite partial functions from ω to 2
--
--

open import Data.List hiding (filter)
open import Data.Maybe

open import ZProduct O

record CountableModel : Set (Level.suc (Level.suc n)) where
   field
       ctl-M : HOD
       ctl→ : ℕ → Ordinal
       ctl<M : (x : ℕ) → odef (ctl-M) (ctl→ x)
       ctl← : (x : Ordinal )→  odef (ctl-M ) x → ℕ
       ctl-iso→ : { x : Ordinal } → (lt : odef (ctl-M) x )  → ctl→ (ctl← x lt ) ≡ x
       -- we have no otherway round
       -- ctl-iso← : { x : ℕ }  →  ctl← (ctl→ x ) (ctl<M x)  ≡ x
--
-- almmost universe
-- find-p contains ∃ x : Ordinal → x o< & M → ∀ r ∈ M → ∈ Ord x
--

-- we expect  P ∈ * ctl-M ∧ G  ⊆ L ⊆ Power P  , ¬ G ∈ * ctl-M,

open CountableModel

abs-minus : {p q : HOD} → (C : CountableModel) → ctl-M C ∋ (p ＼ q) 
abs-minus {p} {q} C = ? where
    p-q : {x : Ordinal } → odef (p ＼ q) x →  ℕ
    p-q pqx = ctl← C _ ?

----
--   a(n) ∈ M
--   ∃ q ∈ L ⊆ Power P → q ∈ a(n) ∧ p(n) ⊆ q
--
PGHOD :  (i : ℕ) (L : HOD) (C : CountableModel ) → (p : Ordinal) → HOD
PGHOD i L C p = record { od = record { def = λ x  →
       odef L x ∧ odef (* (ctl→ C i)) x  ∧  ( (y : Ordinal ) → odef (* p) y →  odef (* x) y ) }
   ; odmax = odmax L  ; <odmax = λ {y} lt → <odmax L (proj1 lt) }

---
--   p(n+1) = if ({q | q ∈ a(n) ∧ p(n) ⊆ q)} != ∅ then q otherwise p(n)
--
find-p :  (L : HOD ) (C : CountableModel )  (i : ℕ) → (x : Ordinal) → Ordinal
find-p L C zero x = x
find-p L C (suc i) x with is-o∅ ( & ( PGHOD i L C (find-p L C i x)) )
... | yes y  = find-p L C i x
... | no not  = & (ODC.minimal O ( PGHOD i L C (find-p L C i x)) (λ eq → not (=od∅→≡o∅ eq)))  -- axiom of choice

---
-- G = { r ∈ L ⊆ Power P | ∃ n → r ⊆ p(n) }
--
record PDN  (L p : HOD ) (C : CountableModel )  (x : Ordinal) : Set n where
   field
       gr : ℕ
       pn<gr : (y : Ordinal) → odef (* x) y → odef (* (find-p L C gr (& p))) y
       x∈PP  : odef L x

open PDN

---
-- G as a HOD
--
PDHOD :  (L p : HOD ) (C : CountableModel  ) → HOD
PDHOD L p C  = record { od = record { def = λ x →  PDN L p C x }
    ; odmax = odmax L ; <odmax = λ {y} lt → <odmax L {y} (PDN.x∈PP lt)  }

open PDN

----
--  Generic Filter on Power P for HOD's Countable Ordinal (G ⊆ Power P ≡ G i.e. ℕ → P → Set )
--
--  p 0 ≡ ∅
--  p (suc n) = if ∃ q ∈ M ∧ p n ⊆ q → q  (by axiom of choice) ( q =  * ( ctl→ n ) )
---             else p n

P∅ : {P : HOD} → odef (Power P) o∅
P∅ {P} =  subst (λ k → odef (Power P) k ) ord-od∅ (lemma o∅  o∅≡od∅) where
    lemma : (x : Ordinal ) → * x ≡ od∅ → odef (Power P) (& od∅)
    lemma x eq = power← P od∅  (λ {x} lt → ⊥-elim (¬x<0 lt ))
x<y→∋ : {x y : Ordinal} → odef (* x) y → * x ∋ * y
x<y→∋ {x} {y} lt = subst (λ k → odef (* x) k ) (sym &iso) lt

gf05 : {a b : HOD} {x : Ordinal } → (odef (a ∪ b) x ) → ¬ odef a x → ¬ odef b x → ⊥
gf05 {a} {b} {x} (case1 ax) nax nbx = nax ax
gf05 {a} {b} {x} (case2 bx) nax nbx = nbx bx

gf02 : {P a b : HOD } → (P ＼ a) ∩ (P ＼ b) ≡ ( P ＼ (a ∪ b) )
gf02 {P} {a} {b} = ==→o≡  record { eq→ = gf03 ; eq← = gf04 }where
       gf03 : {x : Ordinal} → odef ((P ＼ a) ∩ (P ＼ b)) x → odef (P ＼ (a ∪ b)) x
       gf03 {x} ⟪ ⟪ Px , ¬ax ⟫ , ⟪ _ , ¬bx ⟫ ⟫ = ⟪ Px , (λ pab → gf05 {a} {b} {x} pab ¬ax ¬bx )   ⟫
       gf04 : {x : Ordinal} → odef (P ＼ (a ∪ b)) x → odef ((P ＼ a) ∩ (P ＼ b)) x
       gf04 {x} ⟪ Px , abx ⟫  = ⟪ ⟪ Px , (λ ax → abx (case1 ax) ) ⟫ , ⟪ Px  , (λ bx → abx (case2 bx) ) ⟫ ⟫

open import Data.Nat.Properties
open import nat

p-monotonic1 :  (L p : HOD ) (C : CountableModel  ) → {n : ℕ} → (* (find-p L C n (& p))) ⊆ (* (find-p L C (suc n) (& p)))
p-monotonic1 L p C {n} {x} with is-o∅ (& (PGHOD n L C (find-p L C n (& p))))
... | yes y =  refl-⊆ {* (find-p L C n (& p))}
... | no not = λ  lt →   proj2 (proj2 fmin∈PGHOD) _ lt   where
    fmin : HOD
    fmin = ODC.minimal O (PGHOD n L C (find-p L C n (& p))) (λ eq → not (=od∅→≡o∅ eq))
    fmin∈PGHOD : PGHOD n L C (find-p L C n (& p)) ∋ fmin
    fmin∈PGHOD = ODC.x∋minimal O (PGHOD n L C (find-p L C n (& p))) (λ eq → not (=od∅→≡o∅ eq))

p-monotonic :  (L p : HOD ) (C : CountableModel  ) → {n m : ℕ} → n ≤ m → (* (find-p L C n (& p))) ⊆ (* (find-p L C m (& p)))
p-monotonic L p C {zero} {zero} n≤m = refl-⊆ {* (find-p L C zero (& p))}
p-monotonic L p C {zero} {suc m} z≤n lt = p-monotonic1 L p C {m} (p-monotonic L p C {zero} {m} z≤n lt )
p-monotonic L p C {suc n} {suc m} (s≤s n≤m) with <-cmp n m
... | tri< a ¬b ¬c = λ lt → p-monotonic1 L p C {m} (p-monotonic L p C {suc n} {m} a lt)
... | tri≈ ¬a refl ¬c = λ x → x
... | tri> ¬a ¬b c = ⊥-elim ( nat-≤> n≤m c )

record Dense  {L P : HOD } (LP : L ⊆ Power P)  : Set (Level.suc n) where
   field
       dense : HOD
       d⊆P :  dense ⊆ L
       dense-f : {p : HOD} → L ∋ p  → HOD
       dense-d :  { p : HOD} → (lt : L ∋ p) → dense ∋ dense-f lt
       dense-p :  { p : HOD} → (lt : L ∋ p) → p ⊆ dense-f lt

record GenericFilter {L P : HOD} (LP : L ⊆ Power P) (M : HOD) : Set (Level.suc n) where
    field
       genf : Filter {L} {P} LP
       generic : (D : Dense {L} {P} LP ) → M ∋ Dense.dense D → ¬ ( (Dense.dense D ∩ Replace (Filter.filter genf) (λ x → P ＼ x )) ≡ od∅ )
    rgen : HOD
    rgen = Replace (Filter.filter genf) (λ x → P ＼ x )

P-GenericFilter : (P L p0 : HOD ) → (LP : L ⊆ Power P) → L ∋ p0
      → (CAP : {p q : HOD} → L ∋ p → L ∋ q → L ∋ (p ∩ q ))  -- L is a Boolean Algebra
      → (UNI : {p q : HOD} → L ∋ p → L ∋ q → L ∋ (p ∪ q ))
      → (NEG : ({p : HOD} → L ∋ p → L ∋ ( P ＼ p)))
      → (C : CountableModel ) → GenericFilter {L} {P} LP ( ctl-M C )
P-GenericFilter P L p0 L⊆PP Lp0 CAP UNI NEG C = record {
      genf = record { filter = Replace (PDHOD L p0 C) (λ x → P ＼ x)  ; f⊆L =  gf01 ; filter1 = f1 ; filter2 = f2 }
    ; generic = λ D cd → subst (λ k → ¬ (Dense.dense D ∩ k) ≡ od∅ ) (sym gf00) (fdense D cd )
   } where
        GP =  Replace (PDHOD L p0 C) (λ x → P ＼ x)
        f⊆PL :  PDHOD L p0 C ⊆ L
        f⊆PL lt = x∈PP lt
        gf01 : Replace (PDHOD L p0 C) (λ x → P ＼ x) ⊆ L
        gf01 {x} record { z = z ; az = az ; x=ψz = x=ψz } = subst (λ k → odef L k) (sym x=ψz) ( NEG (subst (λ k → odef L k) (sym &iso) (f⊆PL az)) )
        gf141 : {xp xq : Ordinal } → (Pp : PDN L p0 C xp) (Pq : PDN L p0 C xq) →  (* xp ∪ * xq) ⊆ P
        gf141 Pp Pq {x} (case1 xpx) = L⊆PP (PDN.x∈PP Pp)  _ xpx
        gf141 Pp Pq {x} (case2 xqx) = L⊆PP (PDN.x∈PP Pq)  _ xqx
        gf121 : {p q : HOD} (gp : GP ∋ p) (gq : GP ∋ q)  →  p ∩ q  ≡ P ＼ * (& (* (Replaced.z gp) ∪ * (Replaced.z gq)))
        gf121 {p} {q} gp gq = begin
               p ∩ q  ≡⟨ cong₂ (λ j k → j ∩ k ) (sym *iso) (sym *iso)  ⟩
               (* (& p)) ∩ (* (& q))  ≡⟨ cong₂ (λ j k → ( * j ) ∩ ( * k)) (Replaced.x=ψz gp) (Replaced.x=ψz gq) ⟩
               * (& (P ＼ (* xp ))) ∩ (* (& (P ＼ (* xq ))))  ≡⟨ cong₂ (λ j k → j ∩ k ) *iso *iso  ⟩
               (P ＼ (* xp )) ∩ (P ＼ (* xq ))  ≡⟨ gf02 {P} {* xp} {* xq}  ⟩
               P ＼ ((* xp) ∪ (* xq))  ≡⟨ cong (λ k → P ＼ k) (sym *iso) ⟩
               P ＼ * (& (* xp ∪ * xq))  ∎ where
                  open ≡-Reasoning
                  xp = Replaced.z gp
                  xq = Replaced.z gq
        gf131 : {p q : HOD} (gp : GP ∋ p) (gq : GP ∋ q)  →  P ＼ (p ∩ q) ≡ * (Replaced.z gp) ∪ * (Replaced.z gq)
        gf131 {p} {q} gp gq = trans (cong (λ k → P ＼ k) (gf121 gp gq))
          (trans ( L＼Lx=x (subst (λ k → k ⊆ P) (sym *iso) (gf141 (Replaced.az gp) (Replaced.az gq))) ) *iso )

        f1 : {p q : HOD} → L ∋ q → Replace (PDHOD L p0 C) (λ x → P ＼ x) ∋ p → p ⊆ q → Replace (PDHOD L p0 C) (λ x → P ＼ x) ∋ q
        f1 {p} {q} L∋q record { z = z ; az = az ; x=ψz = x=ψz } p⊆q = record { z = _ 
           ; az = record { gr = gr az ;  pn<gr = f04 ; x∈PP = NEG L∋q } ; x=ψz = f05 } where
           open ≡-Reasoning
           f04 : (y : Ordinal) → odef (* (& (P ＼ q))) y → odef (* (find-p L C (gr az ) (& p0))) y
           f04 y qy = PDN.pn<gr az  _ (subst (λ k → odef k y ) f06 (f03 qy ))  where
              f06 : * (& (P ＼ p)) ≡ * z
              f06 = begin
                * (& (P ＼ p)) ≡⟨ *iso ⟩
                P ＼ p ≡⟨ cong (λ k → P ＼ k) (sym *iso)  ⟩
                P ＼ (* (& p)) ≡⟨ cong (λ k → P ＼ k) (cong (*) x=ψz) ⟩
                P ＼ (* (& (P ＼ * z))) ≡⟨ cong ( λ k → P  ＼ k) *iso ⟩
                P ＼ (P ＼ * z) ≡⟨ L＼Lx=x  (λ {x} lt → L⊆PP (x∈PP az) _ lt ) ⟩
                * z ∎ 
              f03 :  odef (* (& (P ＼ q))) y →  odef (* (& (P ＼ p))) y
              f03 pqy with subst (λ k → odef k y ) *iso pqy
              ... | ⟪ Py , nqy ⟫ = subst (λ k → odef k y ) (sym *iso) ⟪ Py , (λ py → nqy (p⊆q py) ) ⟫
           f05 : & q ≡ & (P ＼ * (& (P ＼ q)))
           f05 = cong (&) ( begin
              q ≡⟨ sym (L＼Lx=x (λ {x} lt → L⊆PP L∋q _ (subst (λ k → odef k x) (sym *iso) lt) )) ⟩ 
              P ＼ (P ＼ q )  ≡⟨  cong ( λ k → P  ＼ k) (sym *iso) ⟩ 
              P ＼ * (& (P ＼ q)) ∎ )
        f2 : {p q : HOD} → GP ∋ p → GP ∋ q → L ∋ (p ∩ q) → GP ∋ (p ∩ q)
        f2 {p} {q} record { z = xp ; az = Pp ; x=ψz = peq }
                   record { z = xq ; az = Pq ; x=ψz = qeq } L∋pq with <-cmp (gr Pp) (gr Pq)
        ... | tri< a ¬b ¬c = record { z = & ( (* xp) ∪ (* xq) ) ; az = gf10  ; x=ψz = cong (&) (gf121 gp gq) } where
              gp = record { z = xp ; az = Pp ; x=ψz = peq }
              gq = record { z = xq ; az = Pq ; x=ψz = qeq }
              gf10 : odef (PDHOD L p0 C) (& (* xp ∪ * xq))
              gf10 = record { gr = PDN.gr Pq ; pn<gr = gf15 ; x∈PP = subst (λ k → odef L k) (cong (&) (gf131 gp gq)) ( NEG L∋pq ) } where
                 gf16 : gr Pp ≤ gr Pq
                 gf16 = <to≤ a
                 gf15 :  (y : Ordinal) → odef (* (& (* xp ∪ * xq))) y → odef (* (find-p L C (gr Pq) (& p0))) y
                 gf15 y gpqy with subst (λ k → odef k y ) *iso gpqy
                 ... | case1 xpy = p-monotonic L p0 C gf16 (PDN.pn<gr Pp y xpy )
                 ... | case2 xqy = PDN.pn<gr Pq _ xqy
        ... | tri≈ ¬a eq ¬c = record { z = & (* xp ∪ * xq) ; az = record { gr = gr Pp ; pn<gr = gf21 ; x∈PP = gf22 } ; x=ψz = gf23 } where
              gp = record { z = xp ; az = Pp ; x=ψz = peq }
              gq = record { z = xq ; az = Pq ; x=ψz = qeq }
              gf22 : odef L (& (* xp ∪ * xq))
              gf22 = UNI (subst (λ k → odef L k ) (sym &iso) (PDN.x∈PP Pp)) (subst (λ k → odef L k ) (sym &iso) (PDN.x∈PP Pq))
              gf21 : (y : Ordinal) → odef (* (& (* xp ∪ * xq))) y → odef (* (find-p L C (gr Pp) (& p0))) y
              gf21 y xpqy with subst (λ k → odef k y) *iso xpqy
              ... | case1 xpy = PDN.pn<gr Pp _ xpy
              ... | case2 xqy = subst (λ k → odef (* (find-p L C k (& p0))) y ) (sym eq) ( PDN.pn<gr Pq _ xqy )
              gf25 : odef L (& p)
              gf25 = subst (λ k → odef L k ) (sym peq) ( NEG (subst (λ k → odef L k) (sym &iso) (PDN.x∈PP Pp) ))
              gf27 : {x : Ordinal} → odef p x → odef (P ＼ * xp) x
              gf27 {x} px = subst (λ k → odef k x) (subst₂ (λ j k → j ≡ k ) *iso *iso (cong (*) peq)) px
              -- gf02 : {P a b : HOD } → (P ＼ a) ∩ (P ＼ b) ≡ ( P ＼ (a ∪ b) )
              gf23 : & (p ∩ q) ≡ & (P ＼ * (& (* xp ∪ * xq)))
              gf23 = cong (&) (gf121 gp gq )
        ... | tri> ¬a ¬b c = record { z = & ( (* xp) ∪ (* xq) ) ; az = gf10  ; x=ψz = cong (&) (gf121 gp gq ) } where
              gp = record { z = xp ; az = Pp ; x=ψz = peq }
              gq = record { z = xq ; az = Pq ; x=ψz = qeq }
              gf10 : odef (PDHOD L p0 C) (& (* xp ∪ * xq))
              gf10 = record { gr = PDN.gr Pp ; pn<gr = gf15 ; x∈PP = subst (λ k → odef L k) (cong (&) (gf131 gp gq)) ( NEG L∋pq ) } where
                 gf16 : gr Pq ≤ gr Pp
                 gf16 = <to≤ c
                 gf15 :  (y : Ordinal) → odef (* (& (* xp ∪ * xq))) y → odef (* (find-p L C (gr Pp) (& p0))) y
                 gf15 y gpqy with subst (λ k → odef k y ) *iso gpqy
                 ... | case1 xpy = PDN.pn<gr Pp _ xpy
                 ... | case2 xqy = p-monotonic L p0 C gf16 (PDN.pn<gr Pq y xqy )
        gf00 : Replace (Replace (PDHOD L p0 C) (λ x → P ＼ x)) (_＼_ P) ≡ PDHOD L p0 C
        gf00 = ==→o≡ record { eq→ = gf20 ; eq← = gf22 } where
             gf20 : {x : Ordinal} → odef (Replace (Replace (PDHOD L p0 C) (λ x₁ → P ＼ x₁)) (_＼_ P)) x → PDN L p0 C x
             gf20 {x} record { z = z₁ ; az = record { z = z ; az = az ; x=ψz = x=ψz₁ } ; x=ψz = x=ψz } =
                subst (λ k → PDN L p0 C k ) (begin
                  z ≡⟨ sym &iso ⟩
                  & (* z) ≡⟨ cong (&) (sym (L＼Lx=x gf21 ))  ⟩
                  & (P ＼ ( P ＼ (* z) )) ≡⟨ cong (λ k →  & ( P ＼ k)) (sym *iso)   ⟩
                  & (P ＼ (* ( & (P ＼ (* z )))))  ≡⟨ cong (λ k → & (P ＼ (* k))) (sym x=ψz₁)  ⟩
                  & (P ＼ (* z₁))  ≡⟨  sym x=ψz  ⟩
                  x ∎ ) az where
                  open ≡-Reasoning
                  gf21 : {x : Ordinal } → odef (* z) x → odef P x
                  gf21 {x} lt = L⊆PP ( PDN.x∈PP az) _ lt
             gf22 : {x : Ordinal} → PDN L p0 C x → odef (Replace (Replace (PDHOD L p0 C) (λ x₁ → P ＼ x₁)) (_＼_ P)) x
             gf22 {x} pdx = record { z = _ ; az = record { z = _ ; az = pdx ; x=ψz = refl } ; x=ψz = ( begin
               x ≡⟨ sym &iso ⟩
               & (* x)  ≡⟨ cong (&) (sym (L＼Lx=x gf21 ))  ⟩
               & (P ＼ (P ＼ * x))  ≡⟨ cong (λ k →  & ( P ＼ k)) (sym *iso)   ⟩
               & (P ＼ * (& (P ＼ * x)))  ∎ ) } where
                  open ≡-Reasoning
                  gf21 : {z : Ordinal } → odef (* x) z → odef P z
                  gf21 {z} lt = L⊆PP ( PDN.x∈PP pdx ) z lt
        fdense : (D : Dense {L} {P} L⊆PP ) → (ctl-M C ) ∋ Dense.dense D  → ¬ (Dense.dense D ∩ (PDHOD L p0 C)) ≡ od∅
        fdense D MD eq0  = ⊥-elim (  ∅< {Dense.dense D ∩ PDHOD L p0 C} fd01 (≡od∅→=od∅ eq0 )) where
           open Dense
           fd09 : (i : ℕ ) → odef L (find-p L C i (& p0))
           fd09 zero = Lp0
           fd09 (suc i) with is-o∅ ( & ( PGHOD i L C (find-p L C i (& p0))) )
           ... | yes _ = fd09 i
           ... | no not = fd17 where
              fd19 =  ODC.minimal O ( PGHOD i L C (find-p L C i (& p0))) (λ eq → not (=od∅→≡o∅ eq))  
              fd18 : PGHOD i L C (find-p L C i (& p0)) ∋ fd19
              fd18 = ODC.x∋minimal O (PGHOD i L C (find-p L C i (& p0))) (λ eq → not (=od∅→≡o∅ eq))
              fd17 :  odef L ( & (ODC.minimal O ( PGHOD i L C (find-p L C i (& p0))) (λ eq → not (=od∅→≡o∅ eq)))  )
              fd17 = proj1 fd18 
           an : ℕ
           an = ctl← C (& (dense D)) MD  
           pn : Ordinal
           pn = find-p L C an (& p0)
           pn+1 : Ordinal
           pn+1 = find-p L C (suc an) (& p0)
           d=an : dense D ≡ * (ctl→ C an) 
           d=an = begin dense D ≡⟨ sym *iso ⟩
                    * ( & (dense D)) ≡⟨ cong (*) (sym (ctl-iso→  C MD )) ⟩
                    * (ctl→ C an) ∎  where open ≡-Reasoning
           fd07 : odef (dense D) pn+1
           fd07 with is-o∅ ( & ( PGHOD an L C (find-p L C an (& p0))) )
           ... | yes y = ⊥-elim ( ¬x<0 ( _==_.eq→ fd10 fd21 ) ) where
              L∋pn : L ∋ * (find-p L C an (& p0))
              L∋pn = subst (λ k → odef L k) (sym &iso) (fd09 an )
              L∋df : L ∋ ( dense-f D L∋pn )
              L∋df = (d⊆P D) (  dense-d D L∋pn )
              pn∋df : (* (ctl→ C an)) ∋ ( dense-f D L∋pn )
              pn∋df = subst (λ k → odef k (& ( dense-f D L∋pn ) )) d=an (  dense-d D L∋pn ) 
              pn⊆df : (y : Ordinal) → odef (* (find-p L C an (& p0))) y → odef (* (& (dense-f D L∋pn))) y
              pn⊆df y py = subst (λ k → odef k y ) (sym *iso) (dense-p D L∋pn py)
              fd21 : odef (PGHOD an L C (find-p L C an (& p0)) ) (& (dense-f D L∋pn))
              fd21 = ⟪ L∋df , ⟪ pn∋df , pn⊆df ⟫ ⟫
              fd10 :  PGHOD an L C (find-p L C an (& p0)) =h= od∅
              fd10 = ≡o∅→=od∅ y
           ... | no not = fd27 where
              fd29 =  ODC.minimal O ( PGHOD an L C (find-p L C an (& p0))) (λ eq → not (=od∅→≡o∅ eq))
              fd28 : PGHOD an L C (find-p L C an (& p0)) ∋ fd29
              fd28 = ODC.x∋minimal O (PGHOD an L C (find-p L C an (& p0))) (λ eq → not (=od∅→≡o∅ eq))
              fd27 :  odef (dense D) (& fd29)
              fd27 = subst (λ k → odef k (& fd29)) (sym d=an) (proj1 (proj2 fd28)) 
           fd03 : odef (PDHOD L p0 C) pn+1
           fd03 = record { gr = suc an ; pn<gr = λ y lt → lt ; x∈PP = fd09 (suc an)} 
           fd01 : (dense D ∩ PDHOD L p0 C) ∋ (* pn+1)
           fd01 = ⟪ subst (λ k → odef (dense D)  k ) (sym &iso) fd07 , subst (λ k → odef  (PDHOD L p0 C) k) (sym &iso) fd03 ⟫  


open GenericFilter
open Filter

record NotCompatible  (L p : HOD ) (L∋a : L ∋ p ) : Set (Level.suc (Level.suc n)) where
   field
      q r : HOD
      Lq : L ∋ q
      Lr : L ∋ r
      p⊆q : p ⊆ q  
      p⊆r : p ⊆ r  
      ¬compat : (s : HOD) → ¬ ( (q ⊆ s) ∧ (r ⊆ s) )

lemma232 : (P L p0 : HOD ) → (LPP : L ⊆ Power P) → (Lp0 : L ∋ p0 )
      → (CAP : {p q : HOD} → L ∋ p → L ∋ q → L ∋ (p ∩ q ))  -- L is a Boolean Algebra
      → (UNI : {p q : HOD} → L ∋ p → L ∋ q → L ∋ (p ∪ q ))
      → (NEG : ({p : HOD} → L ∋ p → L ∋ ( P ＼ p)))
      → (C : CountableModel ) 
      → ( MP : ctl-M C ∋ P )
      → ( {p : HOD} → (Lp : L ∋ p ) → NotCompatible L p Lp )
      →  ¬ ( ctl-M C ∋  rgen ( P-GenericFilter P L p0 LPP Lp0 CAP UNI NEG  C ))
lemma232 P L p0 LPP Lp0 CAP UNI NEG C MP NC M∋gf = ¬gf∩D=0 record { eq→ = λ {x} gf∩D → ⊥-elim( proj2 (proj2 gf∩D) (proj1 gf∩D)) 
        ; eq← = λ lt → ⊥-elim (¬x<0 lt) } where
    gf =  rgen ( P-GenericFilter P L p0 LPP Lp0 CAP UNI NEG  C )
    M = ctl-M C
    D : HOD  
    D = L ＼ gf
    M∋D : M ∋ D
    M∋D = subst (λ k → odef M k) ? (ctl<M C ?) 
    D⊆PP : D ⊆ Power P
    D⊆PP {x} ⟪ Lx , ngx ⟫  = LPP Lx 
    DD : Dense {L} {P} LPP
    Dense.dense DD = D
    Dense.d⊆P DD ⟪ Lx , _ ⟫ = Lx
    Dense.dense-f DD Lp = ? where
        ll00 : HOD
        ll00 with NotCompatible.¬compat (NC Lp)
        ... | nc = ? where
           ll01 : {q r : HOD } → (s : HOD) → ¬ ( (q ⊆ s) ∧ (r ⊆ s)) → (¬ (gf ∋ q)) ∨ (¬ (gf ∋ q))
           ll01 = ?
    Dense.dense-d DD = ?
    Dense.dense-p DD = ?
    ¬gf∩D=0 : ¬ ( (gf ∩ D) =h= od∅ )
    ¬gf∩D=0 = ?

--
-- P-Generic Filter defines a countable model D ⊂ C from P
--

--
-- in D, we have V ≠ L
--

--
--   val x G = { val y G | ∃ p → G ∋ p → x ∋ < y , p > }
--

record valR (x : HOD) {P L : HOD} {LP : L ⊆ Power P} (C : CountableModel ) (G : GenericFilter {L} {P} LP (ctl-M C) ) : Set (Level.suc n) where
   field
     valx : HOD

record valS (ox oy oG : Ordinal) : Set n where
   field
     op : Ordinal
     p∈G : odef (* oG) op
     is-val : odef (* ox) ( & < * oy , * op >  )

val : (x : HOD) {P L : HOD } {LP : L ⊆ Power P}
    →  (G : GenericFilter {L} {P} LP {!!} )
    →  HOD
val x G = TransFinite {λ x → HOD } ind (& x) where
  ind : (x : Ordinal) → ((y : Ordinal) → y o< x → HOD) → HOD
  ind x valy = record { od = record { def = λ y → valS x y (& (filter (genf G))) } ; odmax = {!!} ; <odmax = {!!} }