|
1187
|
1 ********************************************************************
|
|
|
2 * Boot - Eliminator WD1002-05 Boot Module
|
|
|
3 *
|
|
|
4 * $Id$
|
|
|
5 *
|
|
|
6 * WD 1002-05 OS-9 Boot Subroutine (called by OS9p1)
|
|
|
7 * Copyright 1988, 1989 Bruce Isted
|
|
|
8 * All Rights Reserved
|
|
|
9 *
|
|
1287
|
10 * Edt/Rev YYYY/MM/DD Modified by
|
|
|
11 * Comment
|
|
1187
|
12 * ------------------------------------------------------------------
|
|
1287
|
13 * 2 ????/??/?? Bruce Isted
|
|
|
14 * Created.
|
|
1187
|
15
|
|
|
16 nam Boot
|
|
|
17 ttl Eliminator WD1002-05 Boot Module
|
|
|
18
|
|
|
19 * These equates should be set before assembly:
|
|
|
20 FDStep equ $09 see Step Rate Table
|
|
|
21 HDStep equ $0F see step rate table
|
|
|
22
|
|
|
23 *Step Rate Table:
|
|
|
24 *+------------------+------------------+------------------+------------------+
|
|
|
25 *! Value=FD/HD Rate ! Value=FD/HD Rate ! Value=FD/HD Rate ! Value=FD/HD Rate !
|
|
|
26 *+------------------+------------------+------------------+------------------+
|
|
|
27 *! $00=40mS/7.5mS ! $04=16mS/5.5mS ! $08=08mS/3.5mS ! $0C=03mS/1.5mS !
|
|
|
28 *! $01=25mS/7.0mS ! $05=14mS/5.0mS ! $09=06mS/3.0mS ! $0D=02mS/1.0mS !
|
|
|
29 *! $02=20mS/6.5mS ! $06=12mS/4.5mS ! $0A=05mS/2.5mS ! $0E=01mS/0.5mS !
|
|
|
30 *! $03=18mS/6.0mS ! $07=10mS/4.0mS ! $0B=04mS/2.0mS ! $0F=15uS/ 35uS !
|
|
|
31 *+------------------+------------------+------------------+------------------+
|
|
|
32
|
|
1287
|
33 IFP1
|
|
1187
|
34 use defsfile
|
|
1287
|
35 ENDC
|
|
1187
|
36
|
|
|
37 * These equates should not have to be changed:
|
|
|
38 BEdtn equ 2
|
|
|
39 BVrsn equ 1
|
|
|
40 MaxCyls equ 1024 maximum cylinders supported
|
|
|
41 MaxHeads equ 16 maximum heads supported
|
|
|
42 MaxSctrs equ 64 maximum sectors per track supported
|
|
|
43 PhysDrv0 equ %10000000 SDH register mask for HD0
|
|
|
44 PhysDrv1 equ %10001000 SDH register mask for HD1
|
|
|
45 PhysDrv2 equ %10010000 SDH register mask for HD2
|
|
|
46 PhysDrv3 equ %00011000 SDH register mask for FD0
|
|
|
47 PhysDrv4 equ %00011010 SDH register mask for FD1
|
|
|
48 PhysDrv5 equ %00011100 SDH register mask for FD2
|
|
|
49 PhysDrv6 equ %00011110 SDH register mask for FD3
|
|
|
50 ReadSctr equ %00100000 read sector command
|
|
|
51 Restore equ %00010000 base restore command
|
|
|
52 SelfTest equ %10010000 WD 1002-05 diagnostic test command
|
|
|
53
|
|
|
54 * HCA memory map:
|
|
|
55 org 0
|
|
|
56 WDData rmb 2 WD 1002-05 sector buffer/task files
|
|
|
57 rmb 2 reserved - do not use
|
|
|
58 PA equ . PIA PA offset
|
|
|
59 DDRA rmb 1 PIA DDRA offset
|
|
|
60 CRA rmb 1 PIA CRA offset
|
|
|
61 PB equ . PIA PB offset
|
|
|
62 DDRB rmb 1 PIA DDRB offset
|
|
|
63 CRB rmb 1 PIA CRB offset
|
|
|
64
|
|
|
65 * WD 1002-05 register definitions:
|
|
|
66 org 0
|
|
|
67 WDBuff rmb 1 WD 1002-05 sector buffer address
|
|
|
68 ErrReg equ . error register address (read)
|
|
|
69 WPCReg rmb 1 write precomp register address (write)
|
|
|
70 SctrCnt rmb 1 sector count register address
|
|
|
71 SctrReg rmb 1 sector number register address
|
|
|
72 CylLow rmb 1 cylinder LSB register address
|
|
|
73 CylHigh rmb 1 cylinder MSB register address
|
|
|
74 SDHReg rmb 1 Size/Drive/Head register address
|
|
|
75 StatReg equ . status register address (read)
|
|
|
76 CmdReg rmb 1 command register address (write)
|
|
|
77
|
|
|
78 org 0
|
|
|
79 U.BSZ rmb 2 boot file size
|
|
|
80 U.BSct rmb 1 number of sectors in boot file
|
|
|
81 U.BT rmb 3 boot file start LSN
|
|
|
82 U.BtStrt rmb 2 boot file start address
|
|
|
83 U.CrtCyl rmb 2 current cylinder number
|
|
|
84 U.CrtSct rmb 1 current sector number
|
|
|
85 U.CrtSid rmb 1 current side (head) number
|
|
|
86 U.Restor rmb 1 restore command incl. step rate code
|
|
|
87 U.SDH rmb 1 base WD Size/Drive/Head register copy
|
|
|
88 U.Sides rmb 1 number of disk sides (heads)
|
|
|
89 U.SPC rmb 2 sectors per cylinder
|
|
|
90 U.SPT rmb 2 sectors per track
|
|
|
91 U.StSctr rmb 1 start sector number (HD=0, FD=1)
|
|
|
92 BootMem equ .
|
|
|
93
|
|
|
94 mod BEnd,BNam,Systm+Objct,ReEnt+BVrsn,BExec,$00
|
|
|
95 BNam fcs "Boot"
|
|
|
96 fcb BEdtn edition number
|
|
|
97
|
|
|
98 * base SDH register table
|
|
|
99 SDHTable equ *
|
|
|
100 fcb PhysDrv0,PhysDrv1,PhysDrv2 base SDH for hard drives
|
|
|
101 fcb PhysDrv3,PhysDrv4,PhysDrv5,PhysDrv6 base SDH for floppys
|
|
|
102 ***
|
|
|
103 * Boot subroutine module
|
|
|
104 *
|
|
|
105 * INPUT: none
|
|
|
106 *
|
|
|
107 * OUTPUT: [D]=size of bootstrap file
|
|
|
108 * [X]=start address of bootstrap file in memory
|
|
|
109 * y,u registers altered
|
|
|
110 *
|
|
|
111 * ERROR OUTPUT: [CC]=carry set
|
|
|
112 * [B]=error code
|
|
|
113 BExec ldy <D.WDAddr get HCA base address (set by auto-boot EPROM)
|
|
|
114 cmpy #$FF40 base address too low?
|
|
|
115 blo UnitErr yes, go report error...
|
|
|
116 cmpy #$FF7F base address too high?
|
|
|
117 bhi UnitErr yes, go report error...
|
|
|
118 lda <D.WDBtDr get boot drive number (set by auto-boot EPROM
|
|
|
119 cmpa #$07 legal drive number?
|
|
|
120 blo InitPIA yes, go initialize PIA...
|
|
|
121 UnitErr ldb #E$Unit
|
|
|
122 coma
|
|
|
123 rts
|
|
|
124
|
|
|
125 DumpRead clr PB,y set WD address to sector buffer
|
|
|
126 DumpR0 lda WDData,y get a byte from WD sector buffer
|
|
|
127 decb done yet?
|
|
|
128 bne DumpR0 no, go dump another byte
|
|
|
129 rts
|
|
|
130 LSN0Info ldb #DD.FMT load number of bytes to dump
|
|
|
131 bsr DumpRead go dump LSN0 up to DD.FMT
|
|
|
132 lda WDData,y get DD.FMT (disk density, sides)
|
|
|
133 anda #$01 mask out all but disk sides bit
|
|
|
134 inca correction to bit coding
|
|
|
135 sta U.Sides,u save disk sides (not valid if HD > 2 heads)
|
|
|
136 ldd WDData,y get DD.SPT (sectors per track)
|
|
|
137 std U.SPT,u
|
|
|
138 ldb #DD.BT-DD.RES load number of bytes to dump
|
|
|
139 bsr DumpRead go dump LSN0 from DD.RES to DD.BT
|
|
|
140 lda WDData,y get DD.BT (boot file start LSN) MSB
|
|
|
141 sta U.BT,u
|
|
|
142 ldd WDData,y get DD.BT (boot file start LSN) LSBs
|
|
|
143 std U.BT+1,u
|
|
|
144 ldd WDData,y get DD.BSZ (boot file size)
|
|
|
145 std U.BSZ,u
|
|
|
146 ldb U.StSctr,u floppy drive? (start sector = 1)
|
|
|
147 bne GotInfo yes, sides info OK, go return
|
|
|
148 ldb #DD.OPT+(PD.SID-PD.OPT)-DD.DAT load number of bytes to dump
|
|
|
149 bsr DumpRead go dump LSN0 from DD.DAT to number of sides in option table
|
|
|
150 lda WDData,y get number of sides from DD.OPT section
|
|
|
151 sta U.Sides,u
|
|
|
152 GotInfo rts
|
|
|
153
|
|
|
154 InitPIA clr CRA,y enable PIA DDRA
|
|
|
155 ldd #$033E [A]=DDRA: PA bits 7-2 = inputs, bits 1-0 = outputs
|
|
|
156 std DDRA,y [B]=CRA: PIA CA2 out high, PA slct, CA1 low to high, no IRQs
|
|
|
157 clr CRB,y enable PIA DDRB
|
|
|
158 lda #$FF [A]=DDRB: PB bits 7-0 all outputs
|
|
|
159 std DDRB,y [B]=CRB: PIA CB2 out high, PB slct, CB1 low to high, no IRQs
|
|
|
160 leas -BootMem,s open up some space for variables
|
|
|
161 leau ,s point [U] to start of variables
|
|
|
162 ldb #BootMem number of bytes to clear
|
|
|
163 leax ,u point [X] to start of variables
|
|
|
164 ClrLoop clr ,x+ initialize a byte to 0
|
|
|
165 decb done yet?
|
|
|
166 bne ClrLoop no, go clear another byte
|
|
|
167 lda #SelfTest WD 1002-05 internal diagnostic command
|
|
|
168 lbsr CmdUpdat go issue WD command, ensure everything is ready...
|
|
|
169 bcs ReadErr error, go report it...
|
|
|
170 lda #Restore!($0F&^HDStep) default to Restore with HD step rate
|
|
|
171 ldb <D.WDBtDr get boot drive number
|
|
|
172 cmpb #$03 hard drive?
|
|
|
173 blo SaveRstr yes, go save HD Restore command...
|
|
|
174 inc U.StSctr,u set start sector to 1 for floppy disks
|
|
|
175 lda #Restore!($0F&^FDStep) get Restore with FD step rate
|
|
|
176 SaveRstr sta U.Restor,u
|
|
|
177 leax SDHTable,pc
|
|
|
178 lda b,x get base SDH register
|
|
|
179 sta U.SDH,u save it...
|
|
|
180 * restore head to track 0
|
|
|
181 lbsr SetupTF go update WD task files (except command)
|
|
|
182 lda U.Restor,u load WD restore command code
|
|
|
183 lbsr CmdUpdat go issue WD command
|
|
|
184 bcs ReadErr error, go report it...
|
|
|
185 * read cylinder 0, head 0, first sector
|
|
|
186 lbsr GetSctr go set up, issue read command
|
|
|
187 bcs ReadErr error, go report it...
|
|
|
188 bsr LSN0Info go get disk info from LSN0
|
|
|
189 ldd U.BSZ,u get boot file size/cylinder offset number
|
|
|
190 bne ChkInfo must be boot file size, go check other LSN0 info...
|
|
|
191 ldd U.BT+1,u get offset cylinder number
|
|
|
192 beq ReadErr must not be boot disk, go report error...
|
|
|
193 cmpd #MaxCyls offset cylinder number OK?
|
|
|
194 bhs ReadErr no, go return error...
|
|
|
195 std U.CrtCyl,u save offset cylinder
|
|
|
196 * read offset cylinder, head 0, first sector
|
|
|
197 lbsr GetSctr go set up, issue read command
|
|
|
198 bcs ReadErr error, go exit...
|
|
|
199 lbsr LSN0Info go get disk info from offset LSN0
|
|
|
200 ldd U.BSZ,u get boot file size
|
|
|
201 beq ReadErr must not be boot disk, go report error...
|
|
|
202 * check LSN0 info
|
|
|
203 ChkInfo ldd U.SPT,u get sectors per track
|
|
|
204 beq ReadErr 0 sectors per track, go return error
|
|
|
205 cmpd #MaxSctrs sectors per track OK?
|
|
|
206 bhi ReadErr no, go return error
|
|
|
207 lda U.Sides,u get disk sides (heads)
|
|
|
208 beq ReadErr 0 sides, go return error
|
|
|
209 cmpa #MaxHeads number of heads OK?
|
|
|
210 bhi ReadErr no, go return error
|
|
|
211 mul calculate sectors per cylinder
|
|
|
212 std U.SPC,u save sectors per cylinder
|
|
|
213 ldd U.BSZ,u get boot file size
|
|
|
214 addd #$00FF round up to even sector...
|
|
|
215 sta U.BSct,u save number of sectors in boot file
|
|
|
216 * calculate boot file start cylinder, head, & sector
|
|
|
217 ldd U.BT+1,u get boot file LSN LSBs
|
|
|
218 ldx U.CrtCyl,u get current (offset) cylinder number
|
|
|
219 CylLoop subd U.SPC,u subtract sectors/cylinder
|
|
|
220 blo ChkBtMSB [D] underflow, go check boot file LSN MSB
|
|
|
221 CylLoop0 leax 1,x increment current cylinder number
|
|
|
222 bne CylLoop no overflow, go do another subtraction
|
|
|
223 ReadErr ldb #E$Read
|
|
|
224 coma set Carry for error
|
|
|
225 leas BootMem,s restore stack pointer
|
|
|
226 rts
|
|
|
227 ChkBtMSB tst U.BT,u boot file LSN MSB = 0?
|
|
|
228 beq GotCyl yes, go determine head number
|
|
|
229 dec U.BT,u decrement boot file LSN MSB
|
|
|
230 bra CylLoop0 go on...
|
|
|
231 GotCyl addd U.SPC,u restore sector number
|
|
|
232 stx U.CrtCyl,u save current cylinder number
|
|
|
233 TrkLoop subd U.SPT,u subtract sectors/track
|
|
|
234 blo GotSide [D] underflow, go save current sector number
|
|
|
235 inc U.CrtSid,u increment current side number
|
|
|
236 bra TrkLoop go do another subtraction
|
|
|
237 GotSide addd U.SPT,u restore sector number
|
|
|
238 stb U.CrtSct,u save it
|
|
|
239 * request boot file memory
|
|
|
240 pshs u save data pointer
|
|
|
241 ldd U.BSZ,u get boot file size
|
|
|
242 os9 F$SRqMem
|
|
|
243 tfr u,x move start address into [X]
|
|
|
244 puls u recover data pointer
|
|
|
245 bcs BtExit0 go return F$SRqMem error
|
|
|
246 stx U.BtStrt,u save boot file start address
|
|
|
247 ldd U.CrtCyl,u get cylinder number
|
|
|
248 bra ChkCyl go check cylinder & get first sector
|
|
|
249
|
|
|
250 * load boot file into memory
|
|
|
251 BootLoad inc U.CrtSct,u move on to next sector
|
|
|
252 lda U.SPT+1,u get sectors per track LSB (MSB is always 0)
|
|
|
253 cmpa U.CrtSct,u done track?
|
|
|
254 bhi LoadSctr no, go get sector
|
|
|
255 clr U.CrtSct,u reset current sector number to 0
|
|
|
256 inc U.CrtSid,u move on to next side
|
|
|
257 lda U.CrtSid,u get side number
|
|
|
258 cmpa U.Sides,u done cylinder?
|
|
|
259 blo LoadSctr no, go get sector
|
|
|
260 clr U.CrtSid,u reset side number to 0
|
|
|
261 ldd U.CrtCyl,u get cylinder number
|
|
|
262 addd #1 move on to next cylinder
|
|
|
263 std U.CrtCyl,u save cylinder number
|
|
|
264 ChkCyl cmpd #MaxCyls cylinder number OK?
|
|
|
265 bhs ReadErr no, go return error
|
|
|
266 LoadSctr bsr GetSctr go get current sector from WD 1002-05
|
|
|
267 bcs ReadErr error, go exit
|
|
|
268 clrb transfer 256 bytes
|
|
|
269 stb PB,y set WD sector buffer address
|
|
|
270 ReadLoop lda WDData,y get byte from WD 1002-05
|
|
|
271 sta ,x+ save byte to buffer
|
|
|
272 decb done yet?
|
|
|
273 bne ReadLoop no, go get another byte
|
|
|
274 dec U.BSct,u count down boot file sectors remaining
|
|
|
275 bne BootLoad
|
|
|
276 clrb clear carry
|
|
|
277 ldd U.BSZ,u get boot file size
|
|
|
278 ldx U.BtStrt,u get boot file start address
|
|
|
279 BtExit0 leas BootMem,s restore stack pointer
|
|
|
280 rts
|
|
|
281
|
|
|
282 GetSctr bsr SetupTF go set up WD task files (except command)
|
|
|
283 lda #ReadSctr load WD read sector command code
|
|
|
284 CmdUpdat ldb #CmdReg load WD command register address
|
|
|
285 bsr TFUpdat go issue command...
|
|
|
286 BusyWait ldb #StatReg
|
|
|
287 stb PB,y set WD status register address
|
|
|
288 BusyW0 ldb WDData,y get WD 1002-05 status
|
|
|
289 bitb #%00000010 valid data? (WD 1002-05 powered & connected?)
|
|
|
290 bne BWErr no, go report error...
|
|
|
291 tstb ensure [CC] sign flag is current
|
|
|
292 bmi BusyW0 yes, go check again
|
|
|
293 ldb WDData,y get valid controller status
|
|
|
294 rorb rotate error bit into carry
|
|
|
295 bcc NoError
|
|
|
296 ldb #ErrReg
|
|
|
297 stb PB,y set WD error register address
|
|
|
298 ldb WDData,y get error register contents
|
|
|
299 bne BWErr
|
|
|
300 NoError clrb
|
|
|
301 rts
|
|
|
302 BWErr comb error, set [CC] Carry...
|
|
|
303 rts
|
|
|
304
|
|
|
305 SetupTF ldd #$01*256+SctrCnt single sector commands only
|
|
|
306 bsr TFUpdat
|
|
|
307 lda U.CrtCyl,u get current cylinder number MSB
|
|
|
308 ldb #CylHigh
|
|
|
309 bsr TFUpdat
|
|
|
310 lda U.CrtCyl+1,u get current cylinder number LSB
|
|
|
311 ldb #CylLow
|
|
|
312 bsr TFUpdat
|
|
|
313 lda U.CrtSct,u get current sector number
|
|
|
314 adda U.StSctr,u add offset...
|
|
|
315 ldb #SctrReg
|
|
|
316 bsr TFUpdat
|
|
|
317 clrb default extended head disabled
|
|
|
318 lda U.CrtSid,u get current side (head) number
|
|
|
319 cmpa #$08 extended head?
|
|
|
320 blo StdHead no, go on...
|
|
|
321 incb set enable code
|
|
|
322 anda #$07 mask out all but standard head number
|
|
|
323 StdHead stb PA,y set extended head enable/disable
|
|
|
324 ora U.SDH,u mask in base SDH copy
|
|
|
325 ldb #SDHReg
|
|
|
326 TfUpdat stb PB,y set WD register address
|
|
|
327 sta WDData,y write data to WD 1002-05
|
|
|
328 rts
|
|
|
329
|
|
1287
|
330 IFGT Level-1
|
|
|
331 * Pad Boot module out to $01D0 exactly
|
|
1187
|
332 Pad fill $39,$1D0-3-*
|
|
1287
|
333 ENDC
|
|
1187
|
334
|
|
|
335 emod
|
|
|
336 BEnd equ *
|
|
|
337 end
|
|
|
338
|
